星星博客 - Powered by Discuz! Board

#!/usr/bin/perl
# file : test.pl
# usage: test.pl [host] [port]
# 利用IO::Poll達到多工的技術
#--加載module
use strict;
use IO::Socket;
#--引用後面的constant
use IO::Poll qw( POLLIN POLLOUT POLLERR POLLHUP);
use Errno qw(EWOULDBLOCK);
#--設定Buffer的最大值
use constant MAXBUF =>8192;
#--忽略掉HANG HUP的Signal
$SIG{PIPE} = 'IGNORE';
#--設定全域變數，兩個buffer兩個flag
my ( $to_stdout,$to_socket,$stdin_done,$sock_done);
#--取得 host and port
my $host = shift or die "Usage: test.pl host [port]\n";
my $port = shift || 'echo';
#--建立Socket
my $socket = IO::Socket::INET->new("$host:$port") or die $@;
my $poll = IO::Poll->new() or die "Can't create IO::Poll object";
#--一開始先將STDIN與$socket放入list中，並將其mask設定為POLLIN準備讀取。
$poll->mask(\*STDIN => POLLIN);
$poll->mask($socket => POLLIN);
#--設定標準輸出與$socket為noblocking mode
$socket->blocking(0); # turn off blockingon the socket
STDOUT->blocking(0); # and on STDOUT
#--main loop，$poll->handles會回傳所有正在監控中的handle
while($poll->handles){
#--等候直到有事件符合
$poll->poll;
# 處理可讀取的事件
for my $handle ($poll->handles(POLLIN|POLLHUP|POLLERR)){
if($handle eq \*STDIN){
#?#93;資料讀取表示STDIN已經終止，否則將資料放入to_socket buffer中
$stdin_done++ unless sysread(STDIN,$to_socket,2048,length $to_socket);
}
elsif($handle eq $socket){
# ?#93;資料讀取表示Socket已經讀取完畢，否則將資料附入to_stdout buffer中
$sock_done++ unless sysread($socket,$to_stdout,2048,length $to_stdout);
}
}
# 處理可寫入的事件
for my $handle ($poll->handles(POLLOUT|POLLERR)){
if($handle eq \*STDOUT){
my $bytes = syswrite(STDOUT,$to_stdout);
# 假若不是EWOULDBLOCK，表示真的有Error發生，所以才無法寫入
unless ($bytes){
next if $! == EWOULDBLOCK;
die "write to stdout failed: $!";
}
# 如果發生Partial Write將已經寫出的先清掉。
substr($to_stdout,0,$bytes) = '';
}
elsif($handle eq $socket){
my $bytes = syswrite($socket,$to_socket);
unless ($bytes){
next if $! == EWOULDBLOCK;
die "write to socket failed: $!";
}
substr($to_socket,0,$bytes) = '';
}
}
} continue {
# 每次While loop執行時都會執行到這兒
# 先設定三個bitmask為0，表示將從list中將該handle移除
my ($outmask,$inmask,$sockmask) = (0,0,0);
# 設定stdout的mask，假如有資料要寫出去，則將其mask設為可寫(POLLOUT)
$outmask = POLLOUT if length $to_stdout > 0;
# 當 to_socket的資料長度比MAXBUF大、或socket已經完結
# 或stdin已經完結，都不成立時，則設定STDIN可讀取。
$inmask = POLLIN unless length $to_socket >= MAXBUF
or ($sock_done || $stdin_done);
# 假如有資料要寫出去，設定$socket為POLLOUT（待寫)
$sockmask = POLLOUT if length $to_socket>0;
# 同STDIN定義，但是|=表示附加上去，因為Socket可以同時讀寫
$sockmask |= POLLIN unless length $to_stdout>=MAXBUF or $sock_done;
# 設定STDIN、STDOUT、Socket三個handle的bitmask
$poll->mask(\*STDIN => $inmask);
$poll->mask(\*STDOUT=> $outmask);
$poll->mask($socket => $sockmask);
# 如果$stdin_done為真且已經?#93;有資料送出至$socket了，則將$socket 關?#93;
$socket->shutdown(1) if $stdin_done and !length($to_socket);
}

复制代码